home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / COAXCHAR.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-27  |  13.9 KB  |  394 lines
  1. 10  'COAXCHAR - Coaxial Cable Characteristics - 02 MAY 94 rev.27 SEP 96
  2. 20  CLS:KEY OFF
  3. 30  IF EX$=""THEN EX$="EXIT"
  4. 40  IF PROG$=""THEN GO$=EX$ ELSE GO$=PROG$
  5. 50  PROG$="coaxchar"
  6. 60  COMMON EX$,PROG$
  7. 70  COLOR 7,0,1
  8. 80  ON ERROR GOTO 110
  9. 90  GOTO 130
  10. 100  '
  11. 110  BEEP:PRINT "Error";ERR;"in line";ERL:END
  12. 120  '
  13. 130  LF=1/LOG(10)    'log factor to convert to base 10
  14. 140  PI=3.14159
  15. 150  DIM C$(50,7)    'coax data
  16. 160  UL$=STRING$(80,205)
  17. 170  U$="###.##"
  18. 180  V$="####.###"
  19. 190  W$="####.##"
  20. 200  '
  21. 210  '.....start
  22. 220  CLS
  23. 230  B=0:C=0:E=0:I=0:O=0:U=0:V=0:ZO=0
  24. 240  GOSUB 1270      'read data
  25. 250  COLOR 15,2
  26. 260  PRINT " COAXIAL CABLE CHARACTERISTICS";TAB(57);"by George Murphy VE3ERP ";
  27. 270  COLOR 1,0:PRINT STRING$(80,223);
  28. 280  COLOR 7,0
  29. 290  LOCATE 3
  30. 300  PRINT "         CONTENTS:
  31. 310  PRINT
  32. 320  PRINT "       - Table of commonly used coaxial cables"
  33. 330  PRINT "       - Attenuation in dB of commonly used coaxial cables"
  34. 340  PRINT "       - Characteristics of an unidentified coaxial cable"
  35. 350  PRINT "       - Transmission line length - physical vs. electrical"
  36. 360  PRINT "       - Transmission line stubs (coaxial cable)"
  37. 370  PRINT UL$;
  38. 380  PRINT " Press number in < > to choose standard units of measure:"
  39. 390  PRINT UL$;
  40. 400  PRINT "   < 1 >  Metric"
  41. 410  PRINT "   < 2 >  U.S.A./Imperial"
  42. 420  PRINT UL$;
  43. 430  PRINT "     or Press < 0 > to EXIT....."
  44. 440  LOCATE 25,11
  45. 450  PRINT "This program is based on a concept by GNEWran Hosinsky, EA8YU";
  46. 460  Z$=INKEY$:IF Z$=""THEN 460
  47. 470  IF Z$="0"THEN CLS:CHAIN GO$
  48. 480  IF Z$="1"THEN UM=0.3048:UM$="m.":GOTO 510
  49. 490  IF Z$="2"THEN UM=1:UM$="ft.":GOTO 510
  50. 500  GOTO 460
  51. 510  VIEW PRINT 10 TO 24:CLS:VIEW PRINT:LOCATE 3
  52. 520  PRINT " Press number in < > for:"
  53. 530  PRINT UL$;
  54. 540  FOR Z=1 TO 5:LOCATE Z+4,3:PRINT "<";Z;">":NEXT Z
  55. 550  Z$=INKEY$:IF Z$=""OR VAL(Z$)>5 THEN 550
  56. 560  IF Z$="1"THEN 1390
  57. 570  IF Z$="2"THEN 2530
  58. 580  IF Z$="3"THEN 1870
  59. 590  IF Z$="4"THEN 2960
  60. 600  IF Z$="5"THEN CLS:CHAIN"coaxstub"
  61. 610  GOTO 550
  62. 620  '
  63. 630  '.....data
  64. 640  '                          dielectric                       attenuation
  65. 650  '  type         dielectric  constant  OD      Z(-)    volts constant
  66. 660  '---------      ----------  -------- ----     ----    ----- ------------
  67. 670  DATA RG-6,         Foam PE,  1.8,    .266,    75.0,    400,  0
  68. 680  DATA RG-8X,        Foam PE,  1.8,    .242,    52.0,    300,  0
  69. 690  DATA RG-8,         PE,       2.32,   .405,    52.0,   4000,  1.11
  70. 700  DATA RG-8 Foam,    Foam PE,  1.6,    .405,    50.0,   1500,  1.00
  71. 710  DATA RG-8A,        PE,       2.32,   .405,    52.0,   5000,  1.11
  72. 720  '
  73. 730  DATA RG-9,         PE,       2.32,   .420,    51.0,   4000,  1.16
  74. 740  DATA RG-9A,        PE,       2.32,   .420,    51.0,   4000,  1.16
  75. 750  DATA RG-9B,        PE,       2.32,   .420,    50.0,   5000,  1.16
  76. 760  DATA RG-11,        PE,       2.32,   .405,    75.0,   4000,  0.89
  77. 770  DATA RG-11 Foam,   Foam PE,  1.6,    .405,    75.0,   1600,  0
  78. 780  '
  79. 790  DATA RG-11A,       PE,       2.32,   .405,    75.0,   5000,  0.89
  80. 800  DATA RG-12,        PE,       2.32,   .475,    75.0,   4000,  1.05
  81. 810  DATA RG-12A,       PE,       2.32,   .475,    75.0,   5000,  1.05
  82. 820  DATA RG-17,        PE,       2.32,   .870,    52.0,  11000,  0.83
  83. 830  DATA RG-17A,       PE,       2.32,   .870,    52.0,  11000,  0.83
  84. 840  '
  85. 850  DATA RG-55,        PE,       2.32,   .216,    53.5,   1900,  0
  86. 860  DATA RG-55A,       PE,       2.32,   .216,    50.0,   1900,  0
  87. 870  DATA RG-55B,       PE,       2.32,   .216,    53.5,   1900,  0
  88. 880  DATA RG-58,        PE,       2.32,   .195,    53.5,   1900,  0.92
  89. 890  DATA RG-58 Foam,   Foam PE,  1.6,    .195,    53.5,    600,  1.15
  90. 900  '
  91. 910  DATA RG-58A,       PE,       2.32,   .195,    53.5,   1900,  1.07
  92. 920  DATA RG-58B,       PE,       2.32,   .195,    53.5,   1900,  0.92
  93. 930  DATA RG-58C,       PE,       2.32,   .195,    50.0,   1900,  1.10
  94. 940  DATA RG-59,        PE,       2.32,   .242,    73.0,   2300,  0.95
  95. 950  DATA RG-59 Foam,   Foam PE,  1.6,    .242,    75.0,    800,  0.95
  96. 960  '
  97. 970  DATA RG-59A,       PE,       2.32,   .242,    73.0,   2300,  0.95
  98. 980  DATA RG-62,    Air Space PE, 1.4,    .242,    93.0,    750,  0.92
  99. 990  DATA RG-62 Foam,   Foam PE,  1.6,    .242,    95.0,    700,  0
  100. 1000  DATA RG-62A,   Air Space PE, 1.4,    .242,    93.0,    750,  0.92
  101. 1010  DATA RG-62B,   Air Space PE, 1.4,    .242,    93.0,    750,  0.92
  102. 1020  '
  103. 1030  DATA RG-133A,      PE,       2.32,   .405,    95.0,   4000,  0
  104. 1040  DATA RG-141,       PTFE,     2.1,    .190,    50.0,   1900,  0.97
  105. 1050  DATA RG-141A,      PTFE,     2.1,    .190,    50.0,   1900,  0.97
  106. 1060  DATA RG-142,       PTFE,     2.1,    .206,    50.0,   1900,  1.05
  107. 1070  DATA RG-142A,      PTFE,     2.1,    .206,    50.0,   1900,  1.05
  108. 1080  '
  109. 1090  DATA RG-142B,      PTFE,     2.1,    .195,    50.0,   1900,  0.99
  110. 1100  DATA RG-174,       PE,       2.32,   .100,    50.0,   1500,  1.57
  111. 1110  DATA RG-213,       PE,       2.32,   .405,    50.0,   5000,  1.12
  112. 1120  DATA RG-214,       PE,       2.32,   .425,    50.0,   5000,  1.18
  113. 1130  DATA RG-215,       PE,       2.32,   .475,    50.0,   5000,  1.32
  114. 1140  '
  115. 1150  DATA RG-216,       PE,       2.32,   .425,    75.0,   5000,  0.94
  116. 1160  DATA RG-223,       PE,       2.32,   .212,    50.0,   1900,  0
  117. 1170  DATA 9913 Belden,   Air Space PE,    1.4,     .405,   50.0,   -   ,  0.88
  118. 1180  DATA 9914 Belden,        Foam PE,    1.6,     .405,   50.0,   -   ,  0
  119. 1190  DATA Alum. 1/2",         Foam PE,    1.6,       .5,   50.0,   2500,  0.54
  120. 1200  '
  121. 1210  DATA Alum. 3/4",         Foam PE,    1.6,      .75,   50.0,   4000,  0.63
  122. 1220  DATA Alum. 7/8",         Foam PE,    1.6,     .875,   50.0,   4500,  0.56
  123. 1230  DATA Alum. 1/2",         Foam PE,    1.6,       .5,   75.0,   2500,  0.53
  124. 1240  DATA Alum. 3/4",         Foam PE,    1.6,      .75,   75.0,   3500,  0.59
  125. 1250  DATA Alum. 7/8",         Foam PE,    1.6,     .875,   75.0,   4000,  0.61
  126. 1260  '
  127. 1270  '.....read data
  128. 1280  OPEN"O",1,"\data\coaxial.fil"
  129. 1290  N=50    'no.of data groups above
  130. 1300   FOR Z=1 TO N
  131. 1310    FOR Y=1 TO 7
  132. 1320    READ C$(Z,Y)
  133. 1330    NEXT Y
  134. 1340    WRITE#1,C$(Z,1);C$(Z,2);C$(Z,3);C$(Z,4);C$(Z,5);C$(Z,6);C$(Z,7)
  135. 1350   NEXT Z
  136. 1360  CLOSE
  137. 1370  RETURN
  138. 1380  '
  139. 1390  '.....display table
  140. 1400  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  141. 1410  '
  142. 1420  PRINT "      Z= impedance, <0xE4!>= dielectric constant, <0xE1!>= dielectric ";
  143. 1430  PRINT "D/d factor"
  144. 1440  PRINT UL$;
  145. 1450  M$=UM$:D$="in.":IF UM$="m."THEN M$=" m.":D$="mm."
  146. 1460  PRINT "              Z   Velocity  pF/   >H/   O.D.                 ";
  147. 1470  PRINT "Max.  Dielectric"
  148. 1480  PRINT " Type         -    factor   ";M$;"   ";M$;"    ";D$;"    <0xE4!>     ";
  149. 1490  PRINT "<0xE1!>      RMS   Material"
  150. 1500  PRINT UL$;
  151. 1510  LN=7
  152. 1520  '
  153. 1530  FOR Y=1 TO N
  154. 1540  LN=LN+1
  155. 1550   PRINT TAB(2);C$(Y,1);             'cable type
  156. 1560    E=VAL(C$(Y,3))                     'dielectric constant
  157. 1570    Z=VAL(C$(Y,5))                     'impedance
  158. 1580    D=10^(Z*SQR(E)/138)                'D/d factor
  159. 1590   PRINT TAB(13);USING "###.#";Z;    'characteristic impedance
  160. 1600    V=1/SQR(E)                         'velocity factor
  161. 1610   PRINT TAB(20);USING ".####";V;    'velocity factor
  162. 1620    C=(7.36*E/(LOG(D)*LF))/UM          'capacitance
  163. 1630   PRINT TAB(26);USING "###.###";C;   'pF/ft.
  164. 1640    U=0.14*LOG(D)*LF/UM                 'inductance
  165. 1650   PRINT TAB(34);USING ".###";U;     '>H/ft.
  166. 1660    OD=VAL(C$(Y,4))                    'O.D. of jacket
  167. 1670  IF UM=1 THEN Q$="###.###"ELSE OD=OD*25.4:Q$="#####.#
  168. 1680   PRINT TAB(38);USING Q$;OD;
  169. 1690   PRINT TAB(45);USING U$;E;
  170. 1700   PRINT TAB(51);USING "###.###";D;    'D/d factor
  171. 1710    RMS=VAL(C$(Y,6))
  172. 1720   IF RMS THEN PRINT TAB(60);USING "##,###";RMS;
  173. 1730   PRINT TAB(68);C$(Y,2);              'dielectric material
  174. 1740   IF LN<24 THEN PRINT "":GOTO 1760
  175. 1750   GOSUB 3810:CLS:LN=0:GOTO 1760
  176. 1760  NEXT Y
  177. 1770  PRINT UL$;
  178. 1780  PRINT " PE =      Polyethylene,        temp.range  -65<UNK! {00F8}> to  +80<UNK! {00F8}>C ";
  179. 1790  PRINT "( -85<UNK! {00F8}> to +176<UNK! {00F8}>F)
  180. 1800  PRINT " Foam PE = Foamed polyethylene, temp.range  -65<UNK! {00F8}> to  +80<UNK! {00F8}>C ";
  181. 1810  PRINT "( -85<UNK! {00F8}> to +176<UNK! {00F8}>F)
  182. 1820  PRINT " PTFE =    TEFLON,              temp.range -250<UNK! {00F8}> to +250<UNK! {00F8}>C ";
  183. 1830  PRINT "(-418<UNK! {00F8}> to +482<UNK! {00F8}>F)
  184. 1840  GOTO 3760
  185. 1850  END
  186. 1860  '
  187. 1870  '.....COAXCALC
  188. 1880  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  189. 1890  PRINT " Press number in < > to describe dielectric material:"
  190. 1900  PRINT UL$;
  191. 1910  PRINT "  < 1 >  PE           (Polyethylene)...........<0xE4!> constant = 2.32"
  192. 1920  PRINT "  < 2 >  PTFE         (Teflon).................<0xE4!> constant = 2.10"
  193. 1930  PRINT "  < 3 >  Foam PE      (Foamed Polyethylene)....<0xE4!> constant = 1.60"
  194. 1940  PRINT "  < 4 >  Air Space PE (Polyethylene)...........<0xE4!> constant = 1.40"
  195. 1950  PRINT "  < 5 >  Air          .........................<0xE4!> constant = 1.00"
  196. 1960  PRINT "  < 6 >  Unknown      .........................................."
  197. 1970  PRINT UL$;
  198. 1980  Z$=INKEY$
  199. 1990  IF VAL(Z$)<1 OR VAL(Z$)>7 THEN 1980
  200. 2000  IF Z$="1"THEN E=2.32:GOTO 2160
  201. 2010  IF Z$="2"THEN E=2.1:GOTO 2160
  202. 2020  IF Z$="3"THEN E=1.6:GOTO 2160
  203. 2030  IF Z$="4"THEN E=1.4:GOTO 2160
  204. 2040  IF Z$="5"THEN E=1:GOTO 2160
  205. 2050  IF Z$="6"THEN 2090
  206. 2060  GOTO 1980
  207. 2070  '
  208. 2080  '.....inputs
  209. 2090  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  210. 2100  PRINT " If dielectric constant is unknown enter a value of 2 for ";
  211. 2110  PRINT "initial calculations."
  212. 2120  PRINT UL$;
  213. 2130    INPUT " ENTER: Dielectric constant....<0xE4!>=";E:GOSUB 2280
  214. 2140  IF E=0 THEN 2130
  215. 2150  '
  216. 2160  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  217. 2170  PRINT " If requested data is unknown press <ENTER> to by-pass request...."
  218. 2180  PRINT UL$;
  219. 2190  IF UM=1 THEN DD=1:DD$="in."ELSE DD=25.4:DD$="mm."
  220. 2200  IF ZO THEN 2220
  221. 2210    INPUT " Impedance (ohms)...............Zo=";ZO:GOSUB 2280
  222. 2220  IF O THEN 2240
  223. 2230    PRINT " I.D. of outer conductor (";DD$;")..";:INPUT O:O=O/DD:GOSUB 2280
  224. 2240  IF I THEN 2260
  225. 2250    PRINT " O.D. of inner conductor (";DD$;")..";:INPUT I:I=I/DD:GOSUB 2280
  226. 2260  GOTO 2200
  227. 2270  '
  228. 2280  '.....calculate
  229. 2290    FOR Y=1 TO 3
  230. 2300  IF B=0 AND E*ZO<>0 THEN X=ZO*SQR(E)/138:B=10^X:GOTO 2340
  231. 2310  IF ZO=0 AND E*B<>0 THEN ZO=138/SQR(E)*LOG(B)*LF:GOTO 2340
  232. 2320  IF B=0 AND I*O<>0  THEN B=O/I:GOTO 2340
  233. 2330  IF E*ZO*B<>0 THEN 2370
  234. 2340    NEXT Y
  235. 2350  RETURN
  236. 2360  '
  237. 2370  LOCATE 3
  238. 2380  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  239. 2390  PRINT " Impedance.............Zo=";USING V$;ZO;:PRINT " -"
  240. 2400  PRINT " Dielectric constant....<0xE4!>=";USING V$;E
  241. 2410  PRINT " Dielectric D/d factor..<0xE1!>=";USING V$;B
  242. 2420    C=7.36*E/(LOG(B)*LF)
  243. 2430  PRINT " Capacitance...........pF=";USING V$;C/UM;:PRINT " pF/";UM$
  244. 2440    U=0.14*LOG(B)*LF
  245. 2450  PRINT " Inductance............>H=";USING V$;U/UM;:PRINT " >H/";UM$
  246. 2460    V=1/SQR(E)
  247. 2470  PRINT " Velocity Factor........V=";USING "   #.####";V
  248. 2480  IF I*O=0 THEN 2510
  249. 2490  PRINT " OD of inner conductor...=";USING V$;O*DD;:PRINT " ";DD$
  250. 2500  PRINT " ID of outer conductor...=";USING V$;I*DD;:PRINT " ";DD$
  251. 2510  GOTO 3760
  252. 2520  '
  253. 2530  '.....line loss in standard cables
  254. 2540  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  255. 2550  GOSUB 3380    'preface
  256. 2560  PRINT UL$;
  257. 2570  PRINT " ENTER: Length of line (";UM$;")....";:INPUT LG:LG=LG/UM
  258. 2580  INPUT " ENTER: Frequency (MHz)....";F
  259. 2590  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  260. 2600  PRINT " Attenuation in dB @";USING V$;F;:PRINT " MHz"
  261. 2610  PRINT " Cable Length:";USING W$;LG*0.3048;:PRINT " m. =";
  262. 2620  PRINT USING W$;LG;:PRINT " ft."
  263. 2630  PRINT UL$;
  264. 2640  LOCATE CSRLIN-1,14:PRINT " Z THENTHENTHENTHENTHEN dB "
  265. 2650  LOCATE CSRLIN-1,40:PRINT " Z THENTHENTHENTHENTHEN dB "
  266. 2660  LOCATE CSRLIN-1,65:PRINT " Z THENTHENTHENTHENTHEN dB "
  267. 2670  FOR X=1 TO 50
  268. 2680   ZO=VAL(C$(X,5))         'impedance
  269. 2690   D=VAL(C$(X,4))*0.9       'arbitrary ID of outer conducter
  270. 2700   E=VAL(C$(X,3))          'dielectric constant
  271. 2710   B=10^(ZO*SQR(E)/138)    'D/d constant
  272. 2720   K=VAL(C$(X,7))          'attenuation constant
  273. 2730  A=1/ZO/D*B*K*SQR(F)*LG/100
  274. 2740  C$(X,6)=STR$(A)          'atten.constant array
  275. 2750  NEXT X
  276. 2760  '
  277. 2770  FOR Y=1 TO 17
  278. 2780  PRINT TAB( 2)C$(Y,   1);STRING$(11-LEN(C$(Y,   1)),".");" ";
  279. 2790  PRINT USING "##.#";VAL(C$(Y,   5));:PRINT " -=";
  280. 2800  IF VAL(C$(Y,6))=0 THEN PRINT " *";:GOTO 2820
  281. 2810  PRINT USING "##.##";VAL(C$(Y   ,6));
  282. 2820  PRINT TAB(28)C$(Y+17,1);STRING$(11-LEN(C$(Y+17,1)),".");" ";
  283. 2830  PRINT USING "##.#";VAL(C$(Y+17,5));:PRINT " -=";
  284. 2840  IF VAL(C$(Y+17,6))=0 THEN PRINT " *";:GOTO 2860
  285. 2850  PRINT USING "##.##";VAL(C$(Y+17,6));
  286. 2860  IF Y=17 THEN PRINT "":GOTO 2910
  287. 2870  PRINT TAB(54)C$(Y+34,1);STRING$(11-LEN(C$(Y+34,1)),".");" ";
  288. 2880  PRINT USING "##.#";VAL(C$(Y+34,5));:PRINT " -=";
  289. 2890  IF VAL(C$(Y+34,6))=0 THEN PRINT " *";:GOTO 2910
  290. 2900  PRINT USING "##.##";VAL(C$(Y+34,6));
  291. 2910  NEXT Y
  292. 2920  PRINT UL$;
  293. 2930  LOCATE ,29:PRINT "* = data not available";
  294. 2940  GOTO 3760
  295. 2950  '
  296. 2960  '.....line length - physical vs. electrical
  297. 2970  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  298. 2980  '
  299. 2990  '.....cable table
  300. 3000  FOR Z=1 TO 9
  301. 3010  FOR Y=0 TO 36 STEP 9
  302. 3020  Z$=STR$(Z+Y)':IF LEN(Z$)<3 THEN Z$=" "+Z$:MID$(Z$,2)="0"
  303. 3030  Y$=Z$+": "+C$(Z+Y,1)
  304. 3040  IF LEN(Y$)<16 THEN Y$=Y$+" ":GOTO 3040
  305. 3050  IF Z<10 AND Y=0 THEN Y$=LEFT$(Y$,15)
  306. 3060  IF Z+Y=45 THEN 3080
  307. 3070  PRINT Y$;
  308. 3080  NEXT Y
  309. 3090  NEXT Z
  310. 3100  PRINT UL$;
  311. 3110  INPUT " ENTER: An item number from above list to select coaxial cable";N
  312. 3120  IF N>=1 AND N<=44 THEN 3140
  313. 3130  BEEP:LOCATE CSRLIN-1:PRINT X$;:LOCATE CSRLIN-1:GOTO 3110
  314. 3140  E=VAL(C$(N,3))
  315. 3150  VF=1/SQR(E)
  316. 3160  INPUT " ENTER: Frequency in MHz..........................";F
  317. 3170  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  318. 3180  PRINT TAB(9);C$(N,1);
  319. 3190  PRINT " Transmission Line Physical Length vs. Electrical Length"
  320. 3200  PRINT UL$;
  321. 3210  W=300/F       'length of wavelength in free space
  322. 3220  L=W*VF        'electrical length in metres
  323. 3230  PRINT "        Frequency.................................";USING V$;F;
  324. 3240  PRINT " MHz=";USING V$;300/F;:PRINT " metres"
  325. 3250  PRINT "        Velocity factor...........................";USING V$;VF
  326. 3260  PRINT "        Length of one wavelength in free space....";USING V$;W;
  327. 3270  PRINT " m. =";USING V$;W/0.3048;:PRINT " ft."
  328. 3280  PRINT "        Length of full wavelength line............";USING V$;L;
  329. 3290  PRINT " m. =";USING V$;L/0.3048;:PRINT " ft."
  330. 3300  PRINT "        Length of  1/2 wavelength line............";USING V$;L/2;
  331. 3310  PRINT " m. =";USING V$;L/2/0.3048;:PRINT " ft."
  332. 3320  PRINT "        Length of  1/4 wavelength line............";USING V$;L/4;
  333. 3330  PRINT " m. =";USING V$;L/4/0.3048;:PRINT " ft."
  334. 3340  PRINT "        Length of  1/8 wavelength line............";USING V$;L/8;
  335. 3350  PRINT " m. =";USING V$;L/8/0.3048;:PRINT " ft."
  336. 3360  GOTO 3760
  337. 3370  '
  338. 3380  '.....line loss preface
  339. 3390  T=7
  340. 3400  PRINT TAB(T);
  341. 3410  PRINT "Line loss in any type of coaxial cable can vary considerably from"
  342. 3420  PRINT TAB(T);
  343. 3430  PRINT "values shown in most published graphs because characteristics can"
  344. 3440  PRINT TAB(T);
  345. 3450  PRINT "vary in the same type of cable from different manufacturers. Also,"
  346. 3460  PRINT TAB(T);
  347. 3470  PRINT "age and condition of the cable can effect the inherent loss, as can"
  348. 3480  PRINT TAB(T);
  349. 3490  PRINT "the installation environment. Therefore any theoretical loss values"
  350. 3500  PRINT TAB(T);
  351. 3510  PRINT "(including those computed by this program) must be considered as"
  352. 3520  PRINT TAB(T);
  353. 3530  PRINT "approximate only. The only reliable way to determine line loss is"
  354. 3540  PRINT TAB(T);
  355. 3550  PRINT "by actual measurement. However, the values computed by this program"
  356. 3560  PRINT TAB(T);
  357. 3570  PRINT "should be accurate enough for most Amateur Radio applications."
  358. 3580  PRINT TAB(T);
  359. 3590  PRINT
  360. 3600  PRINT TAB(T);
  361. 3610  PRINT TAB(T);
  362. 3620  PRINT "The formulae used in this program are adapted from those published"
  363. 3630  PRINT TAB(T);
  364. 3640  PRINT "in the ARRL ANTENNA BOOK, 14th edition, page 3-19, using average"
  365. 3650  PRINT TAB(T);
  366. 3660  PRINT "typical manufacturers' inner conductor and braid factors. Please"
  367. 3670  PRINT TAB(T);
  368. 3680  PRINT "note that the graph on page 3-20 has been revised in later ARRL"
  369. 3690  PRINT TAB(T);
  370. 3700  PRINT "publications and may no longer be valid."
  371. 3710  PRINT
  372. 3720  PRINT TAB(T);
  373. 3730  PRINT "Calculated values are only for properly matched transmission lines."
  374. 3740  RETURN
  375. 3750  '
  376. 3760  '.....end
  377. 3770  GOSUB 3810
  378. 3780  RESTORE:GOTO 210   'start
  379. 3790  END
  380. 3800  '
  381. 3810  'HARDCOPY
  382. 3820  GOSUB 3930:LOCATE 25,2:COLOR 14,6
  383. 3830  PRINT " Press 1 to print screen, 2 to print screen & ";
  384. 3840  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  385. 3850  Z$=INKEY$:IF Z$="3"THEN GOSUB 3930:RETURN
  386. 3860  IF Z$="1"OR Z$="2"THEN GOSUB 3930:GOTO 3880
  387. 3870  GOTO 3850
  388. 3880  FOR QX=1 TO 24:FOR QY=1 TO 80
  389. 3890  LPRINT CHR$(SCREEN(QX,QY));
  390. 3900  NEXT QY:NEXT QX
  391. 3910  IF Z$="2"THEN LPRINT CHR$(12)
  392. 3920  GOTO 3820
  393. 3930  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  394.